【Word】ワードのファイルの結合（複数ファイルを１つにまとめて保存・順番・マクロ・無料ソフト等）する方法

Sub ファイルの統合()
    Dim fld As FileDialog
    Dim myFileName As String 'Wordファイル名
    Dim myFilePath As String 'Wordファイルのパス
    Dim mySecNum As Integer 'セクション番号
    
    'フォルダの選択
    Set fld = Application.FileDialog(msoFileDialogFolderPicker)
    If fld.Show = 0 Then Exit Sub
    myFilePath = fld.SelectedItems(1)
    myFileName = Dir(myFilePath & "\*.doc*")
    
    If myFileName = "" Then
        MsgBox "選択したフォルダ内に、Wordファイルがありません。"
        Exit Sub
    End If
    
    '記録用の新規文書を開く
    Documents.Add
    
    'ファイルのコピー
    Do While myFileName <> ""
        With Selection
            'セクション番号取得
            mySecNum = ActiveDocument.Range(0, Selection.Sections(1).Range.End).Sections.Count
            With ActiveDocument.Sections(mySecNum)
                'ヘッダー名追加
                With .Headers(wdHeaderFooterPrimary)
                    .LinkToPrevious = False
                    If mySecNum Mod 2 = 0 Then
                        .Range.Font.ColorIndex = wdBlue
                    Else
                        .Range.Font.ColorIndex = wdRed
                    End If
                    .Range.Text = myFileName
                End With
            End With
            'ファイルの内容を文書末尾に追記
            .InsertFile FileName:=myFilePath & "\" & myFileName
            .InsertParagraphAfter
            .InsertBreak Type:=wdSectionBreakNextPage
        End With
        myFileName = Dir()
    Loop
End Sub